cloud_compliance_framework

This data source provides information about a single compliance framework, built-in or custom, in the CrowdStrike Falcon Platform. Look the framework up by ID, or with an FQL filter that matches exactly one framework, and reference its attributes in other resources.

API Scopes

The following API scopes are required:

• Cloud Security Policies: READ

Example Usage

terraform {
  required_providers {
    crowdstrike = {
      source = "registry.terraform.io/crowdstrike/crowdstrike"
    }
  }
}

provider "crowdstrike" {
  cloud = "us-2"
}

# Look up a compliance framework by ID, built-in or custom.
data "crowdstrike_cloud_compliance_framework" "by_id" {
  id = "3d67d331-d697-42f2-a3e1-e5db2e5f5f0f"
}

# Look up by name. Name equality is case sensitive and matches the whole name;
# framework names are unique, so this resolves a single framework.
data "crowdstrike_cloud_compliance_framework" "by_name" {
  filter = "compliance_framework_name:'PCI DSS Internal'"
}

# Match part of a name with a case-insensitive wildcard. Keep it narrow: matching
# more than one framework is an error.
data "crowdstrike_cloud_compliance_framework" "by_name_prefix" {
  filter = "compliance_framework_name:*'pci dss internal*'"
}

# Combine properties with "+" to pin a specific built-in benchmark release.
data "crowdstrike_cloud_compliance_framework" "by_name_authority_version" {
  filter = "compliance_framework_name:'CIS Amazon Web Services Foundations Benchmark'+compliance_framework_authority:'CIS'+compliance_framework_version:'1.4.0'"
}

# Reference the data source's attributes elsewhere
output "framework_id" {
  value = data.crowdstrike_cloud_compliance_framework.by_name.id
}

output "framework_authority" {
  value = data.crowdstrike_cloud_compliance_framework.by_name.authority
}

output "framework_version" {
  value = data.crowdstrike_cloud_compliance_framework.by_name.version
}

Filtering

Provide either id to look a framework up directly, or filter to find it with a Falcon Query Language (FQL) expression. A filter must resolve to exactly one framework: the data source fails if it matches none or more than one. Both forms work for built-in frameworks, such as CIS, and custom ones.

The filterable properties are:

• compliance_framework_name
• compliance_framework_version
• compliance_framework_authority

The framework identifier is not filterable; use id to look one up by identifier. See the Example Usage above for filter examples.

Schema

Optional

• filter (String) FQL filter used to find the compliance framework. It must resolve to exactly one framework: the lookup fails if it matches none or more than one. Exactly one of id or filter must be provided. Filterable properties are compliance_framework_name, compliance_framework_version, and compliance_framework_authority. See the Filtering section for examples.
• id (String) Identifier for the compliance framework. Exactly one of id or filter must be provided.

Read-Only

• active (Boolean) Whether the compliance framework is active.
• authority (String) The authority that defines the compliance framework, for example CIS for a built-in benchmark or Custom for a user-defined framework.
• description (String) A description of the compliance framework.
• name (String) The name of the compliance framework.
• version (String) The version of the compliance framework. Custom frameworks are created with version 1.0; built-in frameworks carry the version of the benchmark release.